Microsoft MVP성태의 닷넷 이야기
Graphics: 12. Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader) [링크 복사], [링크+제목 복사]
조회: 2729
글쓴 사람
홈페이지
첨부 파일
 

Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader)

Unity shader에서 다중 패스를 이용한 방법이 은근히 까다롭군요. 아래의 글을 읽고,

유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass
; http://rapapa.net/?p=2723
; https://github.com/inbgche/ShaderMixingSample/blob/master/Assets/Shader/FV_FV.shader

다음과 같이 그대로 베껴서 구현해 봤는데,

//Multi-Pass Shader Test. Rapapa.net
 
Shader "Test/Multi-Pass" {
    Properties {
    } 
 
    SubShader {
 
      Tags {"Queue" = "Geometry" "RenderType" = "Opaque" }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - RED          //
      ////////////////////////////////////////////////////////
 
      Pass {
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
        float4 vertex : POSITION;
        float4 color : COLOR;
        };
 
        struct vertexOutput
        {
        float4 pos : POSITION;
        float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
           return fixed4(1, 0, 0, 1);
        }
 
        ENDCG
      }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - GREEN          //
      ////////////////////////////////////////////////////////
 
      Pass {
 
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
          float4 vertex : POSITION;
          float4 color : COLOR;
        };
 
        struct vertexOutput
        {
          float4 pos : POSITION;
          float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
          return fixed4(i.color.r, 1, 0, 1);
        }
 
        ENDCG
 
      }
  }
 
  Fallback "Diffuse"
}

첫 번째 pass에서 붉은색을 반환하고,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(1, 0, 0, 1);
}

두 번째 pass에서 이전 값의 Red 값과 새롭게 Green 값을 합성한다고 하는데,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(i.color.r, 1, 0, 1);
}

실제로 해보면 진짜 노란색이 나옵니다. 문제는, i.color의 rgb 값이 전부 1이기 때문에 그런 식으로 잘 동작하는 것처럼 보인 것입니다. 일례로 다음과 같이 해도 실행해 보면 노란색이 나옵니다.

fixed4 frag( vertexOutput i) : COLOR {
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.g, 1, 0, 1);
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.b, 1, 0, 1);

    // 이렇게 반환하면 하얀색으로 출력
    return i.color;
}

"유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass" 원 글에서 참조 링크로 걸은 글에 보면,

Rules for Multi-pass Shaders in Unity 
; http://albertshih.blogspot.com/2014/11/rules-for-multi-pass-shaders-in-unity.html

다음과 같이 지적하고 있습니다.

(Each pass has its own properties that will not be "passed" on to other passes. For a list of those properties, check here)


QA에 답변과 종합해 보면,

Q: Can you put two vertex/fragment shaders together?
A: Yes, just put two passes with vertex/fragment shaders right next to each other. The second one will be drawn over the first one. (Note that some properties will be passed on from one pass to the other. For example, if you use a vertex shader to change the mesh geometry, the changes will still be there in the next pass.)


그러니까, 각각의 vertex shader에 들어온 vertexInput.color는 이전 패스에서 넘어온 값이 아닙니다. 이것은 초기화 값으로 Unity의 render target은 기본적으로 "white"로 칠해져 있으므로 다중 패스의 모든 vertex shader는 색상 값이 float4(1, 1, 1, 1)로 넘어오는 것입니다.

그리고, 나중에 실행되는 패스가 이전 패스에서 칠한 값에 상관없이 자신의 값으로 덮어쓰는 결과가 됩니다. 그러니까, 위의 멀티 패스는 전혀 사용할 수 없는 예제인 것입니다.




실제로 멀티 패스가 덧씌우는 동작을 하고 있는지 확인을 해볼까요?

이를 위해서는 투명 렌더링을 해보면 됩니다. 따라서 Blend 및 RednerType 옵션을 설정하고,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        // ...[생략]...
    }
}

첫 번째 패스에서 다음과 같이 Red만 설정하고 렌더링하면,

Pass 
{
    CGPROGRAM

    // ...[생략]...

    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;
        o.pos = UnityObjectToClipPos(v.vertex);
        o.color = v.color;
        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR
    {
        return fixed4(1, 0, 0, 1);
    }
    ENDCG
}

(모델을 Sphere로 했다고 가정했을 때) 화면에는 빨간색 구체가 그려집니다. 반면 fixed4(1,0,0,0)으로 alpha 값을 0으로 반환하면 Blend 옵션으로 인해 아무것도 안 그려지게 됩니다.

이렇게 빨간색 구체가 그려진 상태에서,

multi_pass_1.png

이제 두 번째 패스를 추가하겠습니다.

Pass 
{
    CGPROGRAM

    // ...[생략]...
    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;

        if (v.vertex.x > 0.1) // 로컬 좌표계로 x가 0.1보다 큰 경우에는 Green 색상을 그리고,
        {
            o.color = float4(0, 1, 0, 1);
        }
        else
        {                     // 그렇지 않은 경우 alpha == 0을 주어 그리지 않게 만듦.
            o.color = float4(0, 0, 0, 0);
        }

        o.pos = UnityObjectToClipPos(v.vertex);

        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR 
    {
        return i.color;
    }

    ENDCG
}

중간의 if 문의 역할은 의미를 두고 해석하지 말고, 단순히 덮어쓸 여부를 확인하기 위한 정도로만 보시면 됩니다. 즉, 일부는 Green 색상이 alpha == 1이므로 덮어 그릴 것이고, 일부는 alpha == 0이므로 덮어 그리지 않을 것입니다. 실제로 이것을 실행해 보면 다음과 같이 나옵니다.

multi_pass_2.png

이 정도면 어떤 것인지 확인이 되었겠죠? ^^




참고로, shader 코드는 Pass 외부로 빼서 공통 코드를 공유하는 것이 가능합니다. 즉, 아래와 같이 각각의 pass에서 구현하는 것도 가능하지만,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return fixed4(1, 0, 0, 1);
            }
            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;

                if (v.vertex.x > 0.1)
                {
                    o.color = float4(0, 1, 0, 1);
                }
                else
                {
                    o.color = float4(0, 0, 0, 0);
                }

                o.pos = UnityObjectToClipPos(v.vertex);

                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return i.color;
            }

            ENDCG
        }
    }
}

다음과 같이 CGINCLUDE/ENDCG 쌍을 이용해 외부로 빼서 공통 코드는 재활용하는 것도 가능합니다.

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    CGINCLUDE

        struct vertexInput
        {
            float4 vertex : POSITION;
            float4 color : COLOR;
        };

        struct vertexOutput
        {
            float4 pos : POSITION;
            float4 color : COLOR;
        };

        vertexOutput vert(vertexInput v)
        {
            vertexOutput o;
            o.pos = UnityObjectToClipPos(v.vertex);
            o.color = v.color;
            return o;
        }

        fixed4 frag(vertexOutput i) : COLOR
        {
            return fixed4(1, 0, 0, 1);
        }

        vertexOutput vert2(vertexInput v)
        {
            vertexOutput o;

            if (v.vertex.x > 0.1)
            {
                o.color = float4(0, 1, 0, 1);
            }
            else
            {
                o.color = float4(0, 0, 0, 0);
            }

            o.pos = UnityObjectToClipPos(v.vertex);

            return o;
        }

        fixed4 frag2(vertexOutput i) : COLOR
        {
            return i.color;
        }

    ENDCG

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert2
            #pragma fragment frag2

            ENDCG
        }
    }
}




자, 그럼 우리가 원하는 멀티 패스를 어떻게 구현해야 하는 걸까요? 검색해 보면 다음의 결과가 있군요. ^^

CommandBuffer 를 이용한 Multipass Shader 기법 
; http://scripter.co.kr/298

근데, 좀 복잡합니다. ^^; 예전 글에서 구현한 Gaussian Blur가,

Unity로 실습하는 Shader (7) - Blur (평균값, 가우스, 중간값) 필터
; https://www.sysnet.pe.kr/2/0/11620

사용한 2차원 커널을 1차원 커널로 x와 y에 대해 멀티 패스로 구현하면 된다고 했는데요. "CommandBuffer 를 이용한 Multipass Shader 기법" 글에서 설명한 것처럼 복잡하다면 차라리 2차원 커널을 사용해 단일 shader로 그리는 것이 더 효율적인 것 같습니다.




[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]

[연관 글]





[최초 등록일: ]
[최종 수정일: 7/27/2018 ]

Creative Commons License
이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.
by SeongTae Jeong, mailto:techsharer@outlook.com

비밀번호

댓글 쓴 사람
 




... 16  [17]  18  19  20  21  22  23  24  25  26  27  28  29  30  ...
NoWriterDateCnt.TitleFile(s)
11669정성태8/24/20181705개발 환경 구성: 394. 윈도우 환경에서 elasticsearch의 한글 블로그 검색 인덱스 구성
11668정성태8/28/20181720오류 유형: 478. 윈도우 업데이트(KB4458842) 이후 SQL Server 서비스 시작 오류
11667정성태8/28/20181502오류 유형: 477. "Use Unicode UTF-8 for worldwide language support" 옵션 설정 시 SQL Server 2016 설치 오류 [1]
11666정성태8/22/20181434사물인터넷: 37. 아두이노 - 코딩으로 대신하는 오실레이터 회로의 소리 출력파일 다운로드1
11665정성태8/22/20182003사물인터넷: 36. 오실레이터 회로 동작을 아두이노의 코딩으로 구현하는 방법파일 다운로드1
11664정성태8/22/20182284개발 환경 구성: 393. 윈도우 환경에서 elasticsearch의 한글 형태소 분석기 설치
11663정성태8/25/20182947개발 환경 구성: 392. 윈도우 환경에서 curl.exe를 이용한 elasticsearch 6.x 기본 사용법
11662정성태8/21/20181589사물인터넷: 35. 병렬 회로에서의 커패시터파일 다운로드1
11661정성태8/21/20181530사물인터넷: 34. 트랜지스터 동작 - 컬렉터-이미터 간의 저항 측정파일 다운로드1
11660정성태9/4/20181411사물인터넷: 33. 세라믹 커패시터의 동작 방식파일 다운로드1
11659정성태8/19/20181637사물인터넷: 32. 9V 전압에서 테스트하는 PN2222A 트랜지스터파일 다운로드1
11658정성태8/18/20182515사물인터넷: 31. 커패시터와 RC 회로파일 다운로드3
11657정성태8/21/20182032사물인터넷: 30. 릴레이(Relay) 제어파일 다운로드3
11656정성태8/18/20181202사물인터넷: 29. 트랜지스터와 병렬로 연결한 LED파일 다운로드1
11655정성태8/18/20182071사물인터넷: 28. 저항과 병렬로 연결한 LED파일 다운로드1
11654정성태8/18/20181558사물인터넷: 27. 병렬 회로의 저항, 전압 및 전류파일 다운로드1
11653정성태8/18/20181401사물인터넷: 26. 입력 전압에 따른 LED의 전압/저항 변화파일 다운로드1
11652정성태9/11/20181319사물인터넷: 25. 컬렉터 9V, 베이스에 5V와 3.3V 전압으로 테스트하는 C1815 트랜지스터파일 다운로드1
11651정성태9/4/20182608사물인터넷: 24. 9V 전압에서 테스트하는 C1815 트랜지스터파일 다운로드3
11650정성태8/18/20181420사물인터넷: 23. 가변저항으로 분압파일 다운로드1
11649정성태8/14/20181533사물인터넷: 22. 저항에 따른 전류 테스트파일 다운로드1
11648정성태10/17/20182141사물인터넷: 21. 퓨즈를 이용한 회로 보호파일 다운로드3
11647정성태8/8/20181627오류 유형: 476. 음수의 음수는 여전히 음수가 되는 수(절대값이 음수인 수)
11646정성태8/8/20181403오류 유형: 475. gacutil.exe 실행 시 "Failure initializing gacutil" 오류 발생
11645정성태8/8/20181624오류 유형: 474. 닷넷 COM+ - Failed to load the runtime. [1]
11644정성태8/8/20182169디버깅 기술: 118. windbg - 닷넷 개발자를 위한 MEX Debugging Extension 소개
... 16  [17]  18  19  20  21  22  23  24  25  26  27  28  29  30  ...