Microsoft MVP성태의 닷넷 이야기
글쓴 사람
정성태 (techsharer at outlook.com)
홈페이지
첨부 파일
(연관된 글이 3개 있습니다.)
(시리즈 글이 6개 있습니다.)
Graphics: 15. Unity - shader의 World matrix(unity_ObjectToWorld)를 수작업으로 구성
; https://www.sysnet.pe.kr/2/0/11633

Graphics: 17. Unity - World matrix(unity_ObjectToWorld)로부터 TRS(이동/회전/크기) 행렬로 복원하는 방법
; https://www.sysnet.pe.kr/2/0/11637

Graphics: 18. Unity - World matrix(unity_ObjectToWorld)로부터 Position, Rotation, Scale 값을 복원하는 방법
; https://www.sysnet.pe.kr/2/0/11640

Graphics: 22. Unity - shader의 Camera matrix(UNITY_MATRIX_V)를 수작업으로 구성
; https://www.sysnet.pe.kr/2/0/11692

Graphics: 23. Unity - shader의 원근 투영(Perspective projection) 행렬(UNITY_MATRIX_P)을 수작업으로 구성
; https://www.sysnet.pe.kr/2/0/11695

Graphics: 25. Unity - shader의 직교 투영(Orthographic projection) 행렬(UNITY_MATRIX_P)을 수작업으로 구성
; https://www.sysnet.pe.kr/2/0/11700




Unity - World matrix(unity_ObjectToWorld)로부터 Position, Rotation, Scale 값을 복원하는 방법

지난 글에서,

Unity - shader의 World matrix(unity_ObjectToWorld)를 수작업으로 구성
; https://www.sysnet.pe.kr/2/0/11633

Unity - World matrix(unity_ObjectToWorld)로부터 TRS(이동/회전/크기) 행렬로 복원하는 방법
; https://www.sysnet.pe.kr/2/0/11637

unity_ObjectToWorld 행렬로부터 TRS 행렬까지 복원하는 작업을 해봤습니다. 이번에는 TRS 행렬이 아니라 Unity 에디터의 Transform에 입력한 Position, Rotation, Scale 값을 구해 보겠습니다. 우선, Position의 x, y, z 값은 지난 글에서도 설명했듯이 다음과 같이 구할 수 있습니다.

float x = unity_ObjectToWorld._m03;
float y = unity_ObjectToWorld._m13;
float z = unity_ObjectToWorld._m23;

Scale의 x, y, z도 역시 아래와 같이 unity_ObjectToWorld 행렬로부터 구했었고,

vector sx = vector(unity_ObjectToWorld._m00, unity_ObjectToWorld._m10, unity_ObjectToWorld._m20, 0);
vector sy = vector(unity_ObjectToWorld._m01, unity_ObjectToWorld._m11, unity_ObjectToWorld._m21, 0);
vector sz = vector(unity_ObjectToWorld._m02, unity_ObjectToWorld._m12, unity_ObjectToWorld._m22, 0);

float scaleX = length(sx);
float scaleY = length(sy);
float scaleZ = length(sz);

하지만, Rotation의 경우에는 개별 값으로는 구하지 못하고 행렬로만 복원했었습니다.

float4x4 rotationMatrix;

rotationMatrix[0] = float4(unity_ObjectToWorld._m00 / scaleX, unity_ObjectToWorld._m01 / scaleY, unity_ObjectToWorld._m02 / scaleZ, 0);
rotationMatrix[1] = float4(unity_ObjectToWorld._m10 / scaleX, unity_ObjectToWorld._m11 / scaleY, unity_ObjectToWorld._m12 / scaleZ, 0);
rotationMatrix[2] = float4(unity_ObjectToWorld._m20 / scaleX, unity_ObjectToWorld._m21 / scaleY, unity_ObjectToWorld._m22 / scaleZ, 0);
rotationMatrix[3] = float4(0, 0, 0, 1);

즉, Inspector 창에 입력한 Rotation의 x, y, z 회전 값을 구했던 것은 아닙니다. 그럼, 위의 행렬에서 한번 구해볼까요? ^^

이전 글에서 설명했지만, Unity의 경우 축에 대한 Rotation을 다음과 같은 순서로 곱한다고 했습니다.

RY * RX * RZ 

그리고 각각의 축에 대한 회전인 Rx, Ry, Rz 직교 행렬들은 다음과 같았고.

${
Rx = \begin{bmatrix} 1 & 0 & 0 & 0 \\ 0 & cos \theta & -sin \theta & 0 \\ 0 & sin \theta & cos \theta & 0 \\ 0 & 0 & 0 & 1 \end{bmatrix}
}$

${
Ry = \begin{bmatrix} cos \theta & 0 & sin \theta & 0 \\ 0 & 1 & 0 & 0 \\ -sin \theta & 0 & cos \theta & 0 \\ 0 & 0 & 0 & 1 \end{bmatrix}
}$

${
Rz = \begin{bmatrix} cos \theta & -sin \theta & 0 & 0 \\ sin \theta & cos \theta & 0 & 0 \\ 0 & 0 & 1 & 0 \\ 0 & 0 & 0 & 1 \end{bmatrix}
}$


그렇다면, 저 행렬들을 곱하는 와중에 어딘가는 θ 값 하나가 보존된 곳이 있을지 모릅니다. 실제로 저 값들을 곱한 결과를 정리해 볼까요? ^^ 값을 다음과 같이 대입했을 때,

xcos = cos(θx)
xsin = sin(θx)

ycos = cos(θy)
ysin = sin(θy)

zcos = cos(θz)
zsin = sin(θz)

Ry * Rx 행렬 곱부터 하면 다음과 같이 나옵니다.

${
Ry * Rx = \begin{bmatrix} ycos & xsin * ysin & xcos * ysin & 0
\\ 0 & xcos & -xsin & 0
\\ -ysin & xsin * ycos & xcos * ycos & 0
\\ 0 & 0 & 0 & 1 \end{bmatrix}
}$


다시 이 결과를 Rz 행렬에 곱하겠습니다.

${
R = Ry * Rx * Rz = \begin{bmatrix} ycos * zcos + xsin * ysin * zsin & ycos * -zsin + xsin * ysin * zcos & xcos * ysin & 0
\\ xcos * zsin & xcos * zcos & -xsin & 0
\\ -ysin * zcos + xsin * ycos * zsin & -ysin * -zsin + xsin * ycos * zcos & xcos * ycos & 0
\\ 0 & 0 & 0 & 1 \end{bmatrix}
}$


오호~~~ 정말 R[1,2] = -xsin 값이 단독으로 나왔습니다. 따라서 이 값을 역함수에 대입하면,

θ = asin(-R[1,2])
x = rad2deg(θ);


x의 회전 값을 구할 수 있습니다. 이 값을 알게 되었으니 이제 나머지 단서를 이용해 y, z의 회전 값을 구할 수 있습니다. 가령 "R[0,2] = xcos * ysin"의 공식에서 x의 값을 이미 구했으니 xcos는 상수가 되고 이로부터 아크사인을 이용해 역시 y의 회전 값을 구할 수 있습니다. z의 회전 값 역시 "R[1,0] = xcos * zsin"를 이용해 구할 수 있고.

실제로 octave를 이용해 한번 실습해 볼까요? ^^ x, y, z의 회전 값을 각각 70, 50, 45도로 잡고,

x = deg2rad(70)
y = deg2rad(50)
z = deg2rad(45)

xcos = cos(x)
xsin = sin(x)
ycos = cos(y)
ysin = sin(y)
zcos = cos(z)
zsin = sin(z)

Rx = [1 0 0 0; 0 xcos -xsin 0; 0 xsin xcos 0; 0 0 0 1]
Ry = [ycos 0 ysin 0; 0 1 0 0; -ysin 0 ycos 0; 0 0 0 1]
Rz = [zcos -zsin 0 0; zsin zcos 0 0; 0 0 1 0; 0 0 0 1]

R = Ry * Rx * Rz

xrad = asin(-R(2,3))    # octave에서는 0-based 인덱스가 아니고 1-based 인덱스를 사용
rad2deg(xrad)

xcos = cos(xrad)

yrad = asin(R(1,3) / xcos)
rad2deg(yrad)

zrad = asin(R(2,1) / xcos)
rad2deg(zrad)

다음과 같은 결과를 얻을 수 있습니다.

R =

   0.96353   0.05449   0.26200   0.00000
   0.24184   0.24184  -0.93969   0.00000
  -0.11457   0.96878   0.21985   0.00000
   0.00000   0.00000   0.00000   1.00000

xrad =  1.2217
ans =  70

yrad =  0.87266
ans =  50

zrad =  0.78540
ans =  45.000

원하는 데로, 70, 50, 45로 복원을 했습니다. 그런데, z 값을 구하는 공식이 좀 문제입니다. 행렬 구성을 보면 z 값은 다음의 2가지 공식을 사용할 수 있는데,

R[2,1] = xcos * zsin
R[2,2] = xcos * zcos

위의 octave 스크립트에서는 첫 번째만을 사용한 것입니다. 두 번째 공식도 나오도록 스크립트를 조정하고,

zrad = asin(R(2,1) / xcos)
rad2deg(zrad)

zrad = acos(R(2,2) / xcos)
rad2deg(zrad)

x = 30, y = 50, z = -50일 때로 구해 보면, 각각의 z 값은 다음과 같이 반대가 나옵니다.

zrad = -0.87266
ans = -50

zrad =  0.87266
ans =  50

실제로 Unity에 적용해 보면 -50이 맞습니다. 반면 x = -20, y = -20, z = 100일 때로 구해 보면,

zrad =  1.3963
ans =  80.000

zrad =  1.7453
ans =  100

이번엔 100이 맞는 결과입니다. 따라서 z 각을 구하기 위해 R(2,1)을 이용하든, R(2,2)의 값을 이용하든 특정한 상황에서 틀린 값을 반환해 줍니다.

또한, 이렇게 asin/acos의 인자로 나눗셈 연산의 식을 전달할 때는 cosθ가 0이 나오는 것을 주의해야 합니다. 0으로 나누면 NaN이 출력되기 때문에 shader 코드에서 다음과 같은 조치를 취해야 합니다.

// shader

float yAngle = asin(rotationMatrix[0].z / xcos);
if (isnan(yAngle) == true)
{
    yAngle = 0.0;
}

float zAngle = asin(rotationMatrix[1].x / xcos);
if (isnan(zAngle) == true)
{
    zAngle = 0.0;
}

정확하지도 않은 값을 반환하는데, if 문까지 있는 코드라니... 달갑지 않은 상황입니다.




이렇게 고생하고 있을 무렵, 다음의 책에서 해답을 찾을 수 있었습니다.

수학으로 시작하는 3D 게임 개발
; http://www.yes24.co.kr/24/goods/15291048

140 페이지에 보면, 다음의 공식이 나옵니다.

θx = -asin(M2,3)
θy = atan2(M1,3, M3,3)
θz = atan2(M2,1, M2,2)

이 공식이 재미있는 것은 θx는 그렇다 치고, θy와 θz의 경우 R 행렬에 나왔던 2개의 공식을 모두 활용한다는 점입니다.

θy
    R[1,3] = xcos * ysin
    R[3,3] = xcos * ycos

    R[1,3] / R[3,3] = (xcos * ysin) / (xcos * ycos) = ysin / ycos = tan(θy)
    
θz
    R[2,1] = xcos * zsin
    R[2,2] = xcos * zcos

    R[2,1] / R[3,3] = (xcos 8 zsin) / (xcos * zcos) = zsin / zcos = tan(θz)

아니, 단순히 연립방정식으로 공식 하나에만 대입하면 될 것이라고 생각했는데... 저렇게 2개의 공식을 나눠야 할 거라고 저 같은 민간인이 어떻게 알 수 있겠습니까? ^^;

암튼 이 공식을 shader에서는 다음과 같이 코딩할 수 있습니다.

yAngle = atan2(rotationMatrix[0].z, rotationMatrix[2].z);
zAngle = atan2(rotationMatrix[1].x, rotationMatrix[1].y);

자, 그럼 모든 것이 끝났습니다. 이렇게 shader를 구성하고 Unity 에디터의 Transform 영역에서 Position, Rotation, Scale 값을 변경하면 그대로 값이 반영되는 것을 확인할 수 있습니다. (물론, 부동 소수점 연산의 특성상 미세한 오차는 있습니다.)

아래는 이 글의 모든 내용을 반영한 shader 소스 코드입니다.

Shader "My/worldMatrixShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            float4x4 GetRotationMatrix(float xRadian, float yRadian, float zRadian)
            {
                float sina, cosa;
                sincos(xRadian, sina, cosa);

                float4x4 xMatrix;

                xMatrix[0] = float4(1, 0, 0, 0);
                xMatrix[1] = float4(0, cosa, -sina, 0);
                xMatrix[2] = float4(0, sina, cosa, 0);
                xMatrix[3] = float4(0, 0, 0, 1);

                sincos(yRadian, sina, cosa);

                float4x4 yMatrix;

                yMatrix[0] = float4(cosa, 0, sina, 0);
                yMatrix[1] = float4(0, 1, 0, 0);
                yMatrix[2] = float4(-sina, 0, cosa, 0);
                yMatrix[3] = float4(0, 0, 0, 1);

                sincos(zRadian, sina, cosa);

                float4x4 zMatrix;

                zMatrix[0] = float4(cosa, -sina, 0, 0);
                zMatrix[1] = float4(sina, cosa, 0, 0);
                zMatrix[2] = float4(0, 0, 1, 0);
                zMatrix[3] = float4(0, 0, 0, 1);

                return mul(mul(yMatrix, xMatrix), zMatrix);
            }

            v2f vert (appdata v)
            {
                v2f o;

                float4 pos = v.vertex;

                float4x4 scaleMatrix;

                vector sx = vector(unity_ObjectToWorld._m00, unity_ObjectToWorld._m10, unity_ObjectToWorld._m20, 0);
                vector sy = vector(unity_ObjectToWorld._m01, unity_ObjectToWorld._m11, unity_ObjectToWorld._m21, 0);
                vector sz = vector(unity_ObjectToWorld._m02, unity_ObjectToWorld._m12, unity_ObjectToWorld._m22, 0);

                float scaleX = length(sx);
                float scaleY = length(sy);
                float scaleZ = length(sz);

                scaleMatrix[0] = float4(scaleX, 0, 0, 0);
                scaleMatrix[1] = float4(0, scaleY, 0, 0);
                scaleMatrix[2] = float4(0, 0, scaleZ, 0);
                scaleMatrix[3] = float4(0, 0, 0, 1);

                float4x4 rotationMatrix;

                rotationMatrix[0] = float4(unity_ObjectToWorld._m00 / scaleX, unity_ObjectToWorld._m01 / scaleY, unity_ObjectToWorld._m02 / scaleZ, 0);
                rotationMatrix[1] = float4(unity_ObjectToWorld._m10 / scaleX, unity_ObjectToWorld._m11 / scaleY, unity_ObjectToWorld._m12 / scaleZ, 0);
                rotationMatrix[2] = float4(unity_ObjectToWorld._m20 / scaleX, unity_ObjectToWorld._m21 / scaleY, unity_ObjectToWorld._m22 / scaleZ, 0);
                rotationMatrix[3] = float4(0, 0, 0, 1);

                float xAngle = asin(-rotationMatrix[1].z);
                float yAngle = atan2(rotationMatrix[0].z, rotationMatrix[2].z);
                float zAngle = atan2(rotationMatrix[1].x, rotationMatrix[1].y);

                rotationMatrix = GetRotationMatrix(xAngle, yAngle, zAngle);
                
                float4x4 moveMatrix;

                float xPos = unity_ObjectToWorld._m03;
                float yPos = unity_ObjectToWorld._m13;
                float zPos = unity_ObjectToWorld._m23;

                moveMatrix[0] = float4(1, 0, 0, xPos);
                moveMatrix[1] = float4(0, 1, 0, yPos);
                moveMatrix[2] = float4(0, 0, 1, zPos);
                moveMatrix[3] = float4(0, 0, 0, unity_ObjectToWorld._m33);

                float4x4 transformMatrix = mul(mul(moveMatrix, rotationMatrix), scaleMatrix);
                pos = mul(transformMatrix, pos);

                pos = mul(UNITY_MATRIX_V, pos);
                pos = mul(UNITY_MATRIX_P, pos);
                o.vertex = pos;

                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                return col;
            }
            ENDCG
        }
    }
}

첨부 파일은 "수학으로 시작하는 3D 게임 개발" 책에서 주석으로 남긴 링크가,

Extracting Euler Angles from a Rotation Matrix 
; http://www.insomniacgames.com/mike-day-extracting-euler-angles-from-a-rotation-matrix/

깨져 있어서 웹 검색을 하다가 발견한 해당 글의 pdf 파일입니다.




[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]

[연관 글]






[최초 등록일: ]
[최종 수정일: 8/3/2018]

Creative Commons License
이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.
by SeongTae Jeong, mailto:techsharer at outlook.com

비밀번호

댓글 작성자
 




... 46  47  48  49  50  [51]  52  53  54  55  56  57  58  59  60  ...
NoWriterDateCnt.TitleFile(s)
12369정성태10/12/202013955Windows: 176. Raymond Chen이 한글날에 밝히는 윈도우의 한글 자모 분리 현상 [3]
12368정성태10/12/202010001오류 유형: 668. VSIX 확장 빌드 - The "GetDeploymentPathFromVsixManifest" task failed unexpectedly.
12367정성태10/12/202022790오류 유형: 667. Ubuntu - Temporary failure resolving 'kr.archive.ubuntu.com' [2]
12366정성태10/12/202011738.NET Framework: 950. C# 9.0 - (4) 원시 크기 정수(Native ints) [1]파일 다운로드1
12365정성태10/12/202010635.NET Framework: 949. C# 9.0 - (3) 람다 메서드의 매개 변수 무시(Lambda discard parameters)파일 다운로드1
12364정성태10/11/202011830.NET Framework: 948. C# 9.0 - (2) localsinit 플래그 내보내기 무시(Suppress emitting localsinit flag)파일 다운로드1
12363정성태10/11/202012764.NET Framework: 947. C# 9.0 - (1) 대상으로 형식화된 new 식(Target-typed new expressions) [2]파일 다운로드1
12362정성태10/11/20209562VS.NET IDE: 151. Visual Studio 2019에 .NET 5 rc/preview 적용하는 방법
12361정성태10/11/202011187.NET Framework: 946. C# 9.0을 위한 개발 환경 구성
12360정성태10/8/20208376오류 유형: 666. The type or namespace name '...' does not exist in the namespace 'Microsoft.VisualStudio.TestTools' (are you missing an assembly reference?)
12359정성태10/7/20209902오류 유형: 665. Windows - 재부팅 후 iSCSI 연결이 끊기는 문제
12358정성태10/7/20209936오류 유형: 664. Web Deploy 설치 시 "A newer version of Microsoft Web Deploy 3.6 was found on this machine." 오류 [3]
12357정성태10/7/20207998오류 유형: 663. 이벤트 로그 - The storage optimizer couldn't complete retrim on New Volume
12356정성태10/7/202022936오류 유형: 662. ASP.NET Core와 500.19, 500.21 오류 (0x8007000d)
12355정성태10/3/20208073오류 유형: 661. Hyper-V Linux VM의 Internal 유형의 가상 Switch에 대한 IP 연결이 되지 않는 경우
12354정성태10/2/202021014오류 유형: 660. Web Deploy (msdeploy.axd) 실행 시 오류 기록 [1]
12353정성태10/2/202010812개발 환경 구성: 518. 비주얼 스튜디오에서 IIS 웹 서버로 "Web Deploy"를 이용해 배포하는 방법
12352정성태10/2/202011288개발 환경 구성: 517. Hyper-V Internal 네트워크에 NAT을 이용한 인터넷 연결 제공
12351정성태10/2/202010835오류 유형: 659. Nox 실행이 안 되는 경우 - Unable to bind to the underlying transport for ...
12350정성태9/25/202014330Windows: 175. 윈도우 환경에서 클라이언트 소켓의 최대 접속 수 [2]파일 다운로드1
12349정성태9/25/20209197Linux: 32. Ubuntu 20.04 - docker를 위한 tcp 바인딩 추가
12348정성태9/25/20209940오류 유형: 658. 리눅스 docker - Got permission denied while trying to connect to the Docker daemon socket at unix:///var/run/docker.sock
12347정성태9/25/202024122Windows: 174. WSL 2의 네트워크 통신 방법 [4]
12346정성태9/25/20209190오류 유형: 657. IIS - http://localhost 방문 시 Service Unavailable 503 오류 발생
12345정성태9/25/20208868오류 유형: 656. iisreset 실행 시 "Restart attempt failed." 오류가 발생하지만 웹 서비스는 정상적인 경우파일 다운로드1
12344정성태9/25/202010036Windows: 173. 서비스 관리자에 "IIS Admin Service"가 등록되어 있지 않다면?
... 46  47  48  49  50  [51]  52  53  54  55  56  57  58  59  60  ...