제네릭(Generic) 인자에 대한 메타데이터 등록 확인
다음의 예제로 한번 시작해 볼까요? ^^
using System;
class Generic1<T>
{
public void Method<T1, T2, T3>(T1 arg1, T2 arg2, T3 arg3)
{
Console.WriteLine(arg1);
Console.WriteLine(arg2);
}
}
위의 코드에서 사용된 제네릭 유형은 4개입니다. 하나는 Generic1 타입의 인자로 넘어간 "T"이고, 나머지는 Generic1.Method에 전달된 T1, T2, T3입니다. 이들은 .NET 메타데이터의 TypeSpec 테이블에 등록이 되는데, 과연 몇 개가 등록될까요?
지난번 글을 기억하시는 분은,
TypeRef 메타테이블에 등록되는 타입의 조건
; https://www.sysnet.pe.kr/2/0/1856
이에 대해 2개라고 예상하실 수 있을 것입니다. 왜냐하면 C# 코드에 사용되었다고 해도 실제 IL 코드에 사용되지 않는 한 메타데이터에 등록되지 않기 때문입니다. 실제로 이 때의 IL 코드를 보면 box 연산자에 T1과 T2만 사용된 것을 볼 수 있고 T3는 어디에도 사용되지 않았습니다.
.method public hidebysig instance void Method<T1, T2, T3>(!!T1 arg1, !!T2 arg2, !!T3 arg3) cil managed
{
.maxstack 8
L_0000: nop
L_0001: ldarg.1
L_0002: box !!T1
L_0007: call void [mscorlib]System.Console::WriteLine(object)
L_000c: nop
L_000d: ldarg.2
L_000e: box !!T2
L_0013: call void [mscorlib]System.Console::WriteLine(object)
L_0018: nop
L_0019: ret
}
메타데이터의 TypeSpec 테이블은 ildasm.exe를 이용해 "View" / "MetaInfo" / "Show!" 메뉴(단축키: Ctrl+M)를 선택하면 마지막 부분에 다음과 같이 확인할 수 있습니다.
TypeSpec #1 (1b000001)
-------------------------------------------------------
TypeSpec : MVar!!0
TypeSpec #2 (1b000002)
-------------------------------------------------------
TypeSpec : MVar!!1
자, 그럼 위의 소스 코드에 다음의 클래스를 하나 더 추가해 보겠습니다.
class Generic2<T>
{
public void Method<T1, T2, T3>(T1 arg1, T2 arg2, T3 arg3)
{
Console.WriteLine(arg1);
Console.WriteLine(arg2);
}
}
그럼, TypeSpec 테이블에는 몇 개의 토큰값이 등록되었을까요? 답은 이전과 변함없이 2개입니다. 왜냐하면 메서드의 첫 번째, 두 번째 인자로 사용되었다는 점에서 T1, T2의 역할이 같기 때문입니다. (또한 T3는 사용되지 않았기 때문에 상관없겠고.)
그렇다면 아래의 클래스 2개를 추가하면 또 어떨까요?
class Generic3<T>
{
public void Method<T1, T4, T3>(T1 arg1, T4 arg2, T3 arg3)
{
Console.WriteLine(arg1);
Console.WriteLine(arg2);
// Console.WriteLine(arg3);
}
}
class Generic4<T>
{
public void Method<TELEM>(TELEM arg1)
{
Console.WriteLine(arg1);
}
}
결과는 이번에도 역시 변함없는 2개입니다. 왜냐하면, 제네릭 인자의 이름이 "T2"에서 "T4"로, "T1"에서 "TELEM"으로 바뀌었다고 해도 메서드의 첫 번째와 두 번째라는 점에서는 바뀌지 않았으므로 재사용이 가능하기 때문입니다.
하지만, 위의 Generic3 클래스의 Method 정의에서 "// Console.WriteLine(arg3);" 라인의 주석을 해제한다면 어떻게 될까요? 당연히 이번에는 T3 인자가 사용되므로 IL 코드에 반영이 되고,
.method public hidebysig instance void Method<T1, T4, T3>(!!T1 arg1, !!T4 arg2, !!T3 arg3) cil managed
{
.maxstack 8
L_0000: nop
L_0001: ldarg.1
L_0002: box !!T1
L_0007: call void [mscorlib]System.Console::WriteLine(object)
L_000c: nop
L_000d: ldarg.2
L_000e: box !!T4
L_0013: call void [mscorlib]System.Console::WriteLine(object)
L_0018: nop
L_0019: ldarg.3
L_001a: box !!T3
L_001f: call void [mscorlib]System.Console::WriteLine(object)
L_0024: nop
L_0025: ret
}
이로 인해 TypeSpec 테이블에도 등록됩니다. 그럼 이번에는 아래와 같이 클래스를 추가하면 어떻게 될까요?
class Generic5<T1>
{
public void Method(T1 arg1)
{
Console.WriteLine(arg1);
}
}
이때의 "T1"은 이전에 사용된 메서드의 제네릭 인자의 이름과 같지만 클래스의 제네릭이므로 용도가 다릅니다. .NET Reflector와 같은 역어셈블러는 이럴 때 메서드의 제네릭 인자와 다르다는 점을 표현하기 위해 "!" 느낌표를 하나만 사용합니다.
.method public hidebysig instance void Method(!T1 arg1) cil managed
{
.maxstack 8
L_0000: nop
L_0001: ldarg.1
L_0002: box !T1
L_0007: call void [mscorlib]System.Console::WriteLine(object)
L_000c: nop
L_000d: ret
}
참고로, .NET Reflector에서 보여주는 이런 식의 "!!T1", "!T1" 같은 코드는 엄밀히 실제 IL 바이트를 보여주는 것이 아닙니다. (원래는 4바이트 토큰 값이 들어가 있습니다.)
이렇게 해서 지금까지 사용된 총 4개의 TypeSpec 항목을 ildasm.exe로 확인이 가능합니다.
TypeSpec #1 (1b000001)
-------------------------------------------------------
TypeSpec : MVar!!0
TypeSpec #2 (1b000002)
-------------------------------------------------------
TypeSpec : MVar!!1
TypeSpec #3 (1b000003)
-------------------------------------------------------
TypeSpec : MVar!!2
TypeSpec #4 (1b000004)
-------------------------------------------------------
TypeSpec : Var!0
마지막으로, 관련 글 몇 가지 함께 소개합니다. ^^
닷넷 Generic 타입의 메타 데이터 토큰 값 알아내는 방법
; https://www.sysnet.pe.kr/2/0/1848
값(struct) 형식의 제네릭(Generic) 타입이 박싱되는 경우의 메타데이터 토큰 값
; https://www.sysnet.pe.kr/2/0/1857
[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]