Microsoft MVP성태의 닷넷 이야기
Graphics: 12. Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader) [링크 복사], [링크+제목 복사]
조회: 5379
글쓴 사람
정성태 (techsharer at outlook.com)
홈페이지
첨부 파일
 

Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader)

Unity shader에서 다중 패스를 이용한 방법이 은근히 까다롭군요. 아래의 글을 읽고,

유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass
; http://rapapa.net/?p=2723
; https://github.com/inbgche/ShaderMixingSample/blob/master/Assets/Shader/FV_FV.shader

다음과 같이 그대로 베껴서 구현해 봤는데,

//Multi-Pass Shader Test. Rapapa.net
 
Shader "Test/Multi-Pass" {
    Properties {
    } 
 
    SubShader {
 
      Tags {"Queue" = "Geometry" "RenderType" = "Opaque" }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - RED          //
      ////////////////////////////////////////////////////////
 
      Pass {
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
        float4 vertex : POSITION;
        float4 color : COLOR;
        };
 
        struct vertexOutput
        {
        float4 pos : POSITION;
        float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
           return fixed4(1, 0, 0, 1);
        }
 
        ENDCG
      }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - GREEN          //
      ////////////////////////////////////////////////////////
 
      Pass {
 
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
          float4 vertex : POSITION;
          float4 color : COLOR;
        };
 
        struct vertexOutput
        {
          float4 pos : POSITION;
          float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
          return fixed4(i.color.r, 1, 0, 1);
        }
 
        ENDCG
 
      }
  }
 
  Fallback "Diffuse"
}

첫 번째 pass에서 붉은색을 반환하고,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(1, 0, 0, 1);
}

두 번째 pass에서 이전 값의 Red 값과 새롭게 Green 값을 합성한다고 하는데,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(i.color.r, 1, 0, 1);
}

실제로 해보면 진짜 노란색이 나옵니다. 문제는, i.color의 rgb 값이 전부 1이기 때문에 그런 식으로 잘 동작하는 것처럼 보인 것입니다. 일례로 다음과 같이 해도 실행해 보면 노란색이 나옵니다.

fixed4 frag( vertexOutput i) : COLOR {
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.g, 1, 0, 1);
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.b, 1, 0, 1);

    // 이렇게 반환하면 하얀색으로 출력
    return i.color;
}

"유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass" 원 글에서 참조 링크로 걸은 글에 보면,

Rules for Multi-pass Shaders in Unity 
; http://albertshih.blogspot.com/2014/11/rules-for-multi-pass-shaders-in-unity.html

다음과 같이 지적하고 있습니다.

(Each pass has its own properties that will not be "passed" on to other passes. For a list of those properties, check here)


QA에 답변과 종합해 보면,

Q: Can you put two vertex/fragment shaders together?
A: Yes, just put two passes with vertex/fragment shaders right next to each other. The second one will be drawn over the first one. (Note that some properties will be passed on from one pass to the other. For example, if you use a vertex shader to change the mesh geometry, the changes will still be there in the next pass.)


그러니까, 각각의 vertex shader에 들어온 vertexInput.color는 이전 패스에서 넘어온 값이 아닙니다. 이것은 초기화 값으로 Unity의 render target은 기본적으로 "white"로 칠해져 있으므로 다중 패스의 모든 vertex shader는 색상 값이 float4(1, 1, 1, 1)로 넘어오는 것입니다.

그리고, 나중에 실행되는 패스가 이전 패스에서 칠한 값에 상관없이 자신의 값으로 덮어쓰는 결과가 됩니다. 그러니까, 위의 멀티 패스는 전혀 사용할 수 없는 예제인 것입니다.




실제로 멀티 패스가 덧씌우는 동작을 하고 있는지 확인을 해볼까요?

이를 위해서는 투명 렌더링을 해보면 됩니다. 따라서 Blend 및 RednerType 옵션을 설정하고,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        // ...[생략]...
    }
}

첫 번째 패스에서 다음과 같이 Red만 설정하고 렌더링하면,

Pass 
{
    CGPROGRAM

    // ...[생략]...

    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;
        o.pos = UnityObjectToClipPos(v.vertex);
        o.color = v.color;
        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR
    {
        return fixed4(1, 0, 0, 1);
    }
    ENDCG
}

(모델을 Sphere로 했다고 가정했을 때) 화면에는 빨간색 구체가 그려집니다. 반면 fixed4(1,0,0,0)으로 alpha 값을 0으로 반환하면 Blend 옵션으로 인해 아무것도 안 그려지게 됩니다.

이렇게 빨간색 구체가 그려진 상태에서,

multi_pass_1.png

이제 두 번째 패스를 추가하겠습니다.

Pass 
{
    CGPROGRAM

    // ...[생략]...
    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;

        if (v.vertex.x > 0.1) // 로컬 좌표계로 x가 0.1보다 큰 경우에는 Green 색상을 그리고,
        {
            o.color = float4(0, 1, 0, 1);
        }
        else
        {                     // 그렇지 않은 경우 alpha == 0을 주어 그리지 않게 만듦.
            o.color = float4(0, 0, 0, 0);
        }

        o.pos = UnityObjectToClipPos(v.vertex);

        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR 
    {
        return i.color;
    }

    ENDCG
}

중간의 if 문의 역할은 의미를 두고 해석하지 말고, 단순히 덮어쓸 여부를 확인하기 위한 정도로만 보시면 됩니다. 즉, 일부는 Green 색상이 alpha == 1이므로 덮어 그릴 것이고, 일부는 alpha == 0이므로 덮어 그리지 않을 것입니다. 실제로 이것을 실행해 보면 다음과 같이 나옵니다.

multi_pass_2.png

이 정도면 어떤 것인지 확인이 되었겠죠? ^^




참고로, shader 코드는 Pass 외부로 빼서 공통 코드를 공유하는 것이 가능합니다. 즉, 아래와 같이 각각의 pass에서 구현하는 것도 가능하지만,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return fixed4(1, 0, 0, 1);
            }
            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;

                if (v.vertex.x > 0.1)
                {
                    o.color = float4(0, 1, 0, 1);
                }
                else
                {
                    o.color = float4(0, 0, 0, 0);
                }

                o.pos = UnityObjectToClipPos(v.vertex);

                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return i.color;
            }

            ENDCG
        }
    }
}

다음과 같이 CGINCLUDE/ENDCG 쌍을 이용해 외부로 빼서 공통 코드는 재활용하는 것도 가능합니다.

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    CGINCLUDE

        struct vertexInput
        {
            float4 vertex : POSITION;
            float4 color : COLOR;
        };

        struct vertexOutput
        {
            float4 pos : POSITION;
            float4 color : COLOR;
        };

        vertexOutput vert(vertexInput v)
        {
            vertexOutput o;
            o.pos = UnityObjectToClipPos(v.vertex);
            o.color = v.color;
            return o;
        }

        fixed4 frag(vertexOutput i) : COLOR
        {
            return fixed4(1, 0, 0, 1);
        }

        vertexOutput vert2(vertexInput v)
        {
            vertexOutput o;

            if (v.vertex.x > 0.1)
            {
                o.color = float4(0, 1, 0, 1);
            }
            else
            {
                o.color = float4(0, 0, 0, 0);
            }

            o.pos = UnityObjectToClipPos(v.vertex);

            return o;
        }

        fixed4 frag2(vertexOutput i) : COLOR
        {
            return i.color;
        }

    ENDCG

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert2
            #pragma fragment frag2

            ENDCG
        }
    }
}




자, 그럼 우리가 원하는 멀티 패스를 어떻게 구현해야 하는 걸까요? 검색해 보면 다음의 결과가 있군요. ^^

CommandBuffer 를 이용한 Multipass Shader 기법 
; http://scripter.co.kr/298

근데, 좀 복잡합니다. ^^; 예전 글에서 구현한 Gaussian Blur가,

Unity로 실습하는 Shader (7) - Blur (평균값, 가우스, 중간값) 필터
; https://www.sysnet.pe.kr/2/0/11620

사용한 2차원 커널을 1차원 커널로 x와 y에 대해 멀티 패스로 구현하면 된다고 했는데요. "CommandBuffer 를 이용한 Multipass Shader 기법" 글에서 설명한 것처럼 복잡하다면 차라리 2차원 커널을 사용해 단일 shader로 그리는 것이 더 효율적인 것 같습니다.




[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]

[연관 글]


donaricano-btn



[최초 등록일: ]
[최종 수정일: 7/27/2018 ]

Creative Commons License
이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.
by SeongTae Jeong, mailto:techsharer@outlook.com

비밀번호

댓글 쓴 사람
 




1  2  3  4  5  6  7  8  9  10  11  12  13  14  [15]  ...
NoWriterDateCnt.TitleFile(s)
12139정성태2/9/20201238.NET Framework: 886. C# - Console 응용 프로그램에서 UI 스레드 구현 방법
12138정성태2/9/20201515.NET Framework: 885. C# - 닷넷 응용 프로그램에서 Sqlite 사용 [3]파일 다운로드1
12137정성태2/9/2020740오류 유형: 592. [AhnLab] 경고 - 디버거 실행을 탐지했습니다.
12136정성태9/24/2020710Windows: 168. Windows + S(또는 Q)로 뜨는 작업 표시줄의 검색 바가 동작하지 않는 경우
12135정성태7/9/2020959개발 환경 구성: 468. Nuget 패키지의 로컬 보관 폴더를 옮기는 방법 [1]
12134정성태2/5/20202051.NET Framework: 884. eBEST XingAPI의 C# 래퍼 버전 - XingAPINet Nuget 패키지 [2]파일 다운로드1
12133정성태11/6/2020944디버깅 기술: 161. Windbg 환경에서 확인해 본 .NET 메서드 JIT 컴파일 전과 후 - 두 번째 이야기
12132정성태2/20/20201316.NET Framework: 883. C#으로 구현하는 Win32 API 후킹(예: Sleep 호출 가로채기)파일 다운로드1
12131정성태1/27/20201553개발 환경 구성: 467. LocaleEmulator를 이용해 유니코드를 지원하지 않는(한글이 깨지는) 프로그램을 실행하는 방법
12130정성태1/26/2020852VS.NET IDE: 142. Visual Studio에서 windbg의 "Open Executable..."처럼 EXE를 직접 열어 디버깅을 시작하는 방법
12129정성태1/26/20202777.NET Framework: 882. C# - 키움 Open API+ 사용 시 Registry 등록 없이 KHOpenAPI.ocx 사용하는 방법 [1]
12128정성태1/26/2020965오류 유형: 591. The code execution cannot proceed because mfc100.dll was not found. Reinstalling the program may fix this problem.
12127정성태1/28/2020923.NET Framework: 881. C# DLL에서 제공하는 Win32 export 함수의 내부 동작 방식(VT Fix up Table)파일 다운로드1
12126정성태1/25/2020927.NET Framework: 880. C# - PE 파일로부터 IMAGE_COR20_HEADER 및 VTableFixups 테이블 분석파일 다운로드1
12125정성태1/24/2020706VS.NET IDE: 141. IDE0019 - Use pattern matching
12124정성태1/24/20201601VS.NET IDE: 140. IDE1006 - Naming rule violation: These words must begin with upper case characters: ...
12123정성태1/23/20201245웹: 39. Google Analytics - gtag 함수를 이용해 페이지 URL 수정 및 별도의 이벤트 생성 방법
12122정성태1/22/20201071.NET Framework: 879. C/C++의 UNREFERENCED_PARAMETER 매크로를 C#에서 우회하는 방법(IDE0060 - Remove unused parameter '...')파일 다운로드1
12121정성태1/24/2020749VS.NET IDE: 139. Visual Studio - Error List: "Could not find schema information for the ..."파일 다운로드1
12120정성태1/20/20201045.NET Framework: 878. C# DLL에서 Win32 C/C++처럼 dllexport 함수를 제공하는 방법 - 네 번째 이야기(IL 코드로 직접 구현)파일 다운로드1
12119정성태1/17/20201176디버깅 기술: 160. Windbg 확장 DLL 만들기 (3) - C#으로 만드는 방법
12118정성태1/17/20201195개발 환경 구성: 466. C# DLL에서 Win32 C/C++처럼 dllexport 함수를 제공하는 방법 - 세 번째 이야기 [1]
12117정성태1/15/20201150디버깅 기술: 159. C# - 디버깅 중인 프로세스를 강제로 다른 디버거에서 연결하는 방법파일 다운로드1
12116정성태1/15/2020961디버깅 기술: 158. Visual Studio로 디버깅 시 sos.dll 확장 명령어를 (비롯한 windbg의 다양한 기능을) 수행하는 방법
12115정성태1/14/20201049디버깅 기술: 157. C# - PEB.ProcessHeap을 이용해 디버깅 중인지 확인하는 방법파일 다운로드1
12114정성태1/13/20201474디버깅 기술: 156. C# - PDB 파일로부터 심벌(Symbol) 및 타입(Type) 정보 열거 [1]파일 다운로드3
1  2  3  4  5  6  7  8  9  10  11  12  13  14  [15]  ...