Microsoft MVP성태의 닷넷 이야기
Graphics: 12. Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader) [링크 복사], [링크+제목 복사]
조회: 5077
글쓴 사람
정성태 (techsharer at outlook.com)
홈페이지
첨부 파일
 

Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader)

Unity shader에서 다중 패스를 이용한 방법이 은근히 까다롭군요. 아래의 글을 읽고,

유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass
; http://rapapa.net/?p=2723
; https://github.com/inbgche/ShaderMixingSample/blob/master/Assets/Shader/FV_FV.shader

다음과 같이 그대로 베껴서 구현해 봤는데,

//Multi-Pass Shader Test. Rapapa.net
 
Shader "Test/Multi-Pass" {
    Properties {
    } 
 
    SubShader {
 
      Tags {"Queue" = "Geometry" "RenderType" = "Opaque" }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - RED          //
      ////////////////////////////////////////////////////////
 
      Pass {
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
        float4 vertex : POSITION;
        float4 color : COLOR;
        };
 
        struct vertexOutput
        {
        float4 pos : POSITION;
        float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
           return fixed4(1, 0, 0, 1);
        }
 
        ENDCG
      }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - GREEN          //
      ////////////////////////////////////////////////////////
 
      Pass {
 
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
          float4 vertex : POSITION;
          float4 color : COLOR;
        };
 
        struct vertexOutput
        {
          float4 pos : POSITION;
          float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
          return fixed4(i.color.r, 1, 0, 1);
        }
 
        ENDCG
 
      }
  }
 
  Fallback "Diffuse"
}

첫 번째 pass에서 붉은색을 반환하고,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(1, 0, 0, 1);
}

두 번째 pass에서 이전 값의 Red 값과 새롭게 Green 값을 합성한다고 하는데,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(i.color.r, 1, 0, 1);
}

실제로 해보면 진짜 노란색이 나옵니다. 문제는, i.color의 rgb 값이 전부 1이기 때문에 그런 식으로 잘 동작하는 것처럼 보인 것입니다. 일례로 다음과 같이 해도 실행해 보면 노란색이 나옵니다.

fixed4 frag( vertexOutput i) : COLOR {
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.g, 1, 0, 1);
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.b, 1, 0, 1);

    // 이렇게 반환하면 하얀색으로 출력
    return i.color;
}

"유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass" 원 글에서 참조 링크로 걸은 글에 보면,

Rules for Multi-pass Shaders in Unity 
; http://albertshih.blogspot.com/2014/11/rules-for-multi-pass-shaders-in-unity.html

다음과 같이 지적하고 있습니다.

(Each pass has its own properties that will not be "passed" on to other passes. For a list of those properties, check here)


QA에 답변과 종합해 보면,

Q: Can you put two vertex/fragment shaders together?
A: Yes, just put two passes with vertex/fragment shaders right next to each other. The second one will be drawn over the first one. (Note that some properties will be passed on from one pass to the other. For example, if you use a vertex shader to change the mesh geometry, the changes will still be there in the next pass.)


그러니까, 각각의 vertex shader에 들어온 vertexInput.color는 이전 패스에서 넘어온 값이 아닙니다. 이것은 초기화 값으로 Unity의 render target은 기본적으로 "white"로 칠해져 있으므로 다중 패스의 모든 vertex shader는 색상 값이 float4(1, 1, 1, 1)로 넘어오는 것입니다.

그리고, 나중에 실행되는 패스가 이전 패스에서 칠한 값에 상관없이 자신의 값으로 덮어쓰는 결과가 됩니다. 그러니까, 위의 멀티 패스는 전혀 사용할 수 없는 예제인 것입니다.




실제로 멀티 패스가 덧씌우는 동작을 하고 있는지 확인을 해볼까요?

이를 위해서는 투명 렌더링을 해보면 됩니다. 따라서 Blend 및 RednerType 옵션을 설정하고,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        // ...[생략]...
    }
}

첫 번째 패스에서 다음과 같이 Red만 설정하고 렌더링하면,

Pass 
{
    CGPROGRAM

    // ...[생략]...

    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;
        o.pos = UnityObjectToClipPos(v.vertex);
        o.color = v.color;
        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR
    {
        return fixed4(1, 0, 0, 1);
    }
    ENDCG
}

(모델을 Sphere로 했다고 가정했을 때) 화면에는 빨간색 구체가 그려집니다. 반면 fixed4(1,0,0,0)으로 alpha 값을 0으로 반환하면 Blend 옵션으로 인해 아무것도 안 그려지게 됩니다.

이렇게 빨간색 구체가 그려진 상태에서,

multi_pass_1.png

이제 두 번째 패스를 추가하겠습니다.

Pass 
{
    CGPROGRAM

    // ...[생략]...
    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;

        if (v.vertex.x > 0.1) // 로컬 좌표계로 x가 0.1보다 큰 경우에는 Green 색상을 그리고,
        {
            o.color = float4(0, 1, 0, 1);
        }
        else
        {                     // 그렇지 않은 경우 alpha == 0을 주어 그리지 않게 만듦.
            o.color = float4(0, 0, 0, 0);
        }

        o.pos = UnityObjectToClipPos(v.vertex);

        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR 
    {
        return i.color;
    }

    ENDCG
}

중간의 if 문의 역할은 의미를 두고 해석하지 말고, 단순히 덮어쓸 여부를 확인하기 위한 정도로만 보시면 됩니다. 즉, 일부는 Green 색상이 alpha == 1이므로 덮어 그릴 것이고, 일부는 alpha == 0이므로 덮어 그리지 않을 것입니다. 실제로 이것을 실행해 보면 다음과 같이 나옵니다.

multi_pass_2.png

이 정도면 어떤 것인지 확인이 되었겠죠? ^^




참고로, shader 코드는 Pass 외부로 빼서 공통 코드를 공유하는 것이 가능합니다. 즉, 아래와 같이 각각의 pass에서 구현하는 것도 가능하지만,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return fixed4(1, 0, 0, 1);
            }
            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;

                if (v.vertex.x > 0.1)
                {
                    o.color = float4(0, 1, 0, 1);
                }
                else
                {
                    o.color = float4(0, 0, 0, 0);
                }

                o.pos = UnityObjectToClipPos(v.vertex);

                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return i.color;
            }

            ENDCG
        }
    }
}

다음과 같이 CGINCLUDE/ENDCG 쌍을 이용해 외부로 빼서 공통 코드는 재활용하는 것도 가능합니다.

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    CGINCLUDE

        struct vertexInput
        {
            float4 vertex : POSITION;
            float4 color : COLOR;
        };

        struct vertexOutput
        {
            float4 pos : POSITION;
            float4 color : COLOR;
        };

        vertexOutput vert(vertexInput v)
        {
            vertexOutput o;
            o.pos = UnityObjectToClipPos(v.vertex);
            o.color = v.color;
            return o;
        }

        fixed4 frag(vertexOutput i) : COLOR
        {
            return fixed4(1, 0, 0, 1);
        }

        vertexOutput vert2(vertexInput v)
        {
            vertexOutput o;

            if (v.vertex.x > 0.1)
            {
                o.color = float4(0, 1, 0, 1);
            }
            else
            {
                o.color = float4(0, 0, 0, 0);
            }

            o.pos = UnityObjectToClipPos(v.vertex);

            return o;
        }

        fixed4 frag2(vertexOutput i) : COLOR
        {
            return i.color;
        }

    ENDCG

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert2
            #pragma fragment frag2

            ENDCG
        }
    }
}




자, 그럼 우리가 원하는 멀티 패스를 어떻게 구현해야 하는 걸까요? 검색해 보면 다음의 결과가 있군요. ^^

CommandBuffer 를 이용한 Multipass Shader 기법 
; http://scripter.co.kr/298

근데, 좀 복잡합니다. ^^; 예전 글에서 구현한 Gaussian Blur가,

Unity로 실습하는 Shader (7) - Blur (평균값, 가우스, 중간값) 필터
; https://www.sysnet.pe.kr/2/0/11620

사용한 2차원 커널을 1차원 커널로 x와 y에 대해 멀티 패스로 구현하면 된다고 했는데요. "CommandBuffer 를 이용한 Multipass Shader 기법" 글에서 설명한 것처럼 복잡하다면 차라리 2차원 커널을 사용해 단일 shader로 그리는 것이 더 효율적인 것 같습니다.




[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]

[연관 글]





[최초 등록일: ]
[최종 수정일: 7/27/2018 ]

Creative Commons License
이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.
by SeongTae Jeong, mailto:techsharer@outlook.com

비밀번호

댓글 쓴 사람
 




... 16  17  18  19  20  21  22  23  [24]  25  26  27  28  29  30  ...
NoWriterDateCnt.TitleFile(s)
11851정성태3/19/20192514Linux: 8. C# - 리눅스 환경에서 DllImport 대신 라이브러리 동적 로드 처리
11850정성태3/18/20191705.NET Framework: 813. C# async 메서드에서 out/ref/in 유형의 인자를 사용하지 못하는 이유
11849정성태3/18/20192547.NET Framework: 812. pscp.exe 기능을 C#으로 제어하는 방법파일 다운로드1
11848정성태3/17/20191453스크립트: 14. 윈도우 CMD - 파일이 변경된 경우 파일명을 변경해 복사하고 싶다면?
11847정성태3/17/20193008Linux: 7. 리눅스 C/C++ - 공유 라이브러리 동적 로딩 후 export 함수 사용 방법파일 다운로드1
11846정성태3/15/20192453Linux: 6. getenv, setenv가 언어/운영체제마다 호환이 안 되는 문제
11845정성태3/15/20193220Linux: 5. Linux 응용 프로그램의 (C++) so 의존성 줄이기(ReleaseMinDependency) [3]
11844정성태5/22/20193617개발 환경 구성: 434. Visual Studio 2019 - 리눅스 프로젝트를 이용한 공유/실행(so/out) 프로그램 개발 환경 설정 [1]파일 다운로드1
11843정성태3/14/20191640기타: 75. MSDN 웹 사이트를 기본으로 영문 페이지로 열고 싶다면?
11842정성태5/3/20191521개발 환경 구성: 433. 마이크로소프트의 CoreCLR 프로파일러 예제를 Visual Studio CMake로 빌드하는 방법 [1]파일 다운로드1
11841정성태3/13/20191437VS.NET IDE: 132. Visual Studio 2019 - CMake의 컴파일러를 기본 g++에서 clang++로 변경
11840정성태3/13/20191599오류 유형: 526. 윈도우 10 Ubuntu App 환경에서는 USB 외장 하드 접근 불가
11839정성태3/12/20192287디버깅 기술: 124. .NET Core 웹 앱을 호스팅하는 Azure App Services의 프로세스 메모리 덤프 및 windbg 분석 개요 [3]
11838정성태5/9/20193019.NET Framework: 811. (번역글) .NET Internals Cookbook Part 1 - Exceptions, filters and corrupted processes [1]파일 다운로드1
11837정성태10/14/20199024기타: 74. 도서: 시작하세요! C# 7.3 프로그래밍 [10]
11836정성태10/12/20192368오류 유형: 525. Visual Studio 2019 Preview 4/RC - C# 8.0 Missing compiler required member 'System.Range..ctor' [1]
11835정성태3/5/20192651.NET Framework: 810. C# 8.0의 Index/Range 연산자를 .NET Framework에서 사용하는 방법 및 비동기 스트림의 컴파일 방법 [2]파일 다운로드1
11834정성태3/4/20191977개발 환경 구성: 432. Visual Studio 없이 최신 C# (8.0) 컴파일러를 사용하는 방법
11833정성태5/14/20192608개발 환경 구성: 431. Visual Studio 2019 - CMake를 이용한 공유/실행(so/out) 리눅스 프로젝트 설정파일 다운로드1
11832정성태3/4/20191741오류 유형: 524. Visual Studio CMake - rsync: connection unexpectedly closed
11831정성태3/4/20191456오류 유형: 523. Visual Studio 2019 - 새 창으로 뜬 윈도우를 닫을 때 비정상 종료
11830정성태2/26/20191328오류 유형: 522. 이벤트 로그 - Error opening event log file State. Log will not be processed. Return code from OpenEventLog is 87.
11829정성태12/12/20191678개발 환경 구성: 430. 마이크로소프트의 CoreCLR 프로파일러 예제 빌드 방법 - 리눅스 환경 [1]
11828정성태9/24/20204434개발 환경 구성: 429. Component Services 관리자의 RuntimeBroker 설정이 2개 있는 경우 [3]
11827정성태2/26/20192158오류 유형: 521. Visual Studio - Could not start the 'rsync' command on the remote host, please install it using your system package manager.
11826정성태2/26/20191781오류 유형: 520. 우분투에 .NET Core SDK 설치 시 패키지 의존성 오류
... 16  17  18  19  20  21  22  23  [24]  25  26  27  28  29  30  ...