Microsoft MVP성태의 닷넷 이야기
Graphics: 12. Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader) [링크 복사], [링크+제목 복사]
조회: 5383
글쓴 사람
정성태 (techsharer at outlook.com)
홈페이지
첨부 파일
 

Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader)

Unity shader에서 다중 패스를 이용한 방법이 은근히 까다롭군요. 아래의 글을 읽고,

유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass
; http://rapapa.net/?p=2723
; https://github.com/inbgche/ShaderMixingSample/blob/master/Assets/Shader/FV_FV.shader

다음과 같이 그대로 베껴서 구현해 봤는데,

//Multi-Pass Shader Test. Rapapa.net
 
Shader "Test/Multi-Pass" {
    Properties {
    } 
 
    SubShader {
 
      Tags {"Queue" = "Geometry" "RenderType" = "Opaque" }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - RED          //
      ////////////////////////////////////////////////////////
 
      Pass {
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
        float4 vertex : POSITION;
        float4 color : COLOR;
        };
 
        struct vertexOutput
        {
        float4 pos : POSITION;
        float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
           return fixed4(1, 0, 0, 1);
        }
 
        ENDCG
      }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - GREEN          //
      ////////////////////////////////////////////////////////
 
      Pass {
 
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
          float4 vertex : POSITION;
          float4 color : COLOR;
        };
 
        struct vertexOutput
        {
          float4 pos : POSITION;
          float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
          return fixed4(i.color.r, 1, 0, 1);
        }
 
        ENDCG
 
      }
  }
 
  Fallback "Diffuse"
}

첫 번째 pass에서 붉은색을 반환하고,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(1, 0, 0, 1);
}

두 번째 pass에서 이전 값의 Red 값과 새롭게 Green 값을 합성한다고 하는데,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(i.color.r, 1, 0, 1);
}

실제로 해보면 진짜 노란색이 나옵니다. 문제는, i.color의 rgb 값이 전부 1이기 때문에 그런 식으로 잘 동작하는 것처럼 보인 것입니다. 일례로 다음과 같이 해도 실행해 보면 노란색이 나옵니다.

fixed4 frag( vertexOutput i) : COLOR {
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.g, 1, 0, 1);
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.b, 1, 0, 1);

    // 이렇게 반환하면 하얀색으로 출력
    return i.color;
}

"유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass" 원 글에서 참조 링크로 걸은 글에 보면,

Rules for Multi-pass Shaders in Unity 
; http://albertshih.blogspot.com/2014/11/rules-for-multi-pass-shaders-in-unity.html

다음과 같이 지적하고 있습니다.

(Each pass has its own properties that will not be "passed" on to other passes. For a list of those properties, check here)


QA에 답변과 종합해 보면,

Q: Can you put two vertex/fragment shaders together?
A: Yes, just put two passes with vertex/fragment shaders right next to each other. The second one will be drawn over the first one. (Note that some properties will be passed on from one pass to the other. For example, if you use a vertex shader to change the mesh geometry, the changes will still be there in the next pass.)


그러니까, 각각의 vertex shader에 들어온 vertexInput.color는 이전 패스에서 넘어온 값이 아닙니다. 이것은 초기화 값으로 Unity의 render target은 기본적으로 "white"로 칠해져 있으므로 다중 패스의 모든 vertex shader는 색상 값이 float4(1, 1, 1, 1)로 넘어오는 것입니다.

그리고, 나중에 실행되는 패스가 이전 패스에서 칠한 값에 상관없이 자신의 값으로 덮어쓰는 결과가 됩니다. 그러니까, 위의 멀티 패스는 전혀 사용할 수 없는 예제인 것입니다.




실제로 멀티 패스가 덧씌우는 동작을 하고 있는지 확인을 해볼까요?

이를 위해서는 투명 렌더링을 해보면 됩니다. 따라서 Blend 및 RednerType 옵션을 설정하고,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        // ...[생략]...
    }
}

첫 번째 패스에서 다음과 같이 Red만 설정하고 렌더링하면,

Pass 
{
    CGPROGRAM

    // ...[생략]...

    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;
        o.pos = UnityObjectToClipPos(v.vertex);
        o.color = v.color;
        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR
    {
        return fixed4(1, 0, 0, 1);
    }
    ENDCG
}

(모델을 Sphere로 했다고 가정했을 때) 화면에는 빨간색 구체가 그려집니다. 반면 fixed4(1,0,0,0)으로 alpha 값을 0으로 반환하면 Blend 옵션으로 인해 아무것도 안 그려지게 됩니다.

이렇게 빨간색 구체가 그려진 상태에서,

multi_pass_1.png

이제 두 번째 패스를 추가하겠습니다.

Pass 
{
    CGPROGRAM

    // ...[생략]...
    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;

        if (v.vertex.x > 0.1) // 로컬 좌표계로 x가 0.1보다 큰 경우에는 Green 색상을 그리고,
        {
            o.color = float4(0, 1, 0, 1);
        }
        else
        {                     // 그렇지 않은 경우 alpha == 0을 주어 그리지 않게 만듦.
            o.color = float4(0, 0, 0, 0);
        }

        o.pos = UnityObjectToClipPos(v.vertex);

        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR 
    {
        return i.color;
    }

    ENDCG
}

중간의 if 문의 역할은 의미를 두고 해석하지 말고, 단순히 덮어쓸 여부를 확인하기 위한 정도로만 보시면 됩니다. 즉, 일부는 Green 색상이 alpha == 1이므로 덮어 그릴 것이고, 일부는 alpha == 0이므로 덮어 그리지 않을 것입니다. 실제로 이것을 실행해 보면 다음과 같이 나옵니다.

multi_pass_2.png

이 정도면 어떤 것인지 확인이 되었겠죠? ^^




참고로, shader 코드는 Pass 외부로 빼서 공통 코드를 공유하는 것이 가능합니다. 즉, 아래와 같이 각각의 pass에서 구현하는 것도 가능하지만,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return fixed4(1, 0, 0, 1);
            }
            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;

                if (v.vertex.x > 0.1)
                {
                    o.color = float4(0, 1, 0, 1);
                }
                else
                {
                    o.color = float4(0, 0, 0, 0);
                }

                o.pos = UnityObjectToClipPos(v.vertex);

                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return i.color;
            }

            ENDCG
        }
    }
}

다음과 같이 CGINCLUDE/ENDCG 쌍을 이용해 외부로 빼서 공통 코드는 재활용하는 것도 가능합니다.

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    CGINCLUDE

        struct vertexInput
        {
            float4 vertex : POSITION;
            float4 color : COLOR;
        };

        struct vertexOutput
        {
            float4 pos : POSITION;
            float4 color : COLOR;
        };

        vertexOutput vert(vertexInput v)
        {
            vertexOutput o;
            o.pos = UnityObjectToClipPos(v.vertex);
            o.color = v.color;
            return o;
        }

        fixed4 frag(vertexOutput i) : COLOR
        {
            return fixed4(1, 0, 0, 1);
        }

        vertexOutput vert2(vertexInput v)
        {
            vertexOutput o;

            if (v.vertex.x > 0.1)
            {
                o.color = float4(0, 1, 0, 1);
            }
            else
            {
                o.color = float4(0, 0, 0, 0);
            }

            o.pos = UnityObjectToClipPos(v.vertex);

            return o;
        }

        fixed4 frag2(vertexOutput i) : COLOR
        {
            return i.color;
        }

    ENDCG

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert2
            #pragma fragment frag2

            ENDCG
        }
    }
}




자, 그럼 우리가 원하는 멀티 패스를 어떻게 구현해야 하는 걸까요? 검색해 보면 다음의 결과가 있군요. ^^

CommandBuffer 를 이용한 Multipass Shader 기법 
; http://scripter.co.kr/298

근데, 좀 복잡합니다. ^^; 예전 글에서 구현한 Gaussian Blur가,

Unity로 실습하는 Shader (7) - Blur (평균값, 가우스, 중간값) 필터
; https://www.sysnet.pe.kr/2/0/11620

사용한 2차원 커널을 1차원 커널로 x와 y에 대해 멀티 패스로 구현하면 된다고 했는데요. "CommandBuffer 를 이용한 Multipass Shader 기법" 글에서 설명한 것처럼 복잡하다면 차라리 2차원 커널을 사용해 단일 shader로 그리는 것이 더 효율적인 것 같습니다.




[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]

[연관 글]


donaricano-btn



[최초 등록일: ]
[최종 수정일: 7/27/2018 ]

Creative Commons License
이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.
by SeongTae Jeong, mailto:techsharer@outlook.com

비밀번호

댓글 쓴 사람
 




... 16  17  18  19  20  21  22  23  [24]  25  26  27  28  29  30  ...
NoWriterDateCnt.TitleFile(s)
11914정성태5/24/20192957Linux: 10. 윈도우의 GetTickCount와 리눅스의 clock_gettime파일 다운로드1
11913정성태5/24/20191879.NET Framework: 838. C# - 숫자형 타입의 bit(2진) 문자열, 16진수 문자열 구하는 방법파일 다운로드1
11912정성태5/23/20191969VS.NET IDE: 137. Visual Studio 2019 버전 16.1부터 리눅스 C/C++ 프로젝트에 추가된 WSL 지원
11911정성태5/23/20192028VS.NET IDE: 136. Visual Studio 2019 - 리눅스 C/C++ 프로젝트에 인텔리센스가 동작하지 않는 경우
11910정성태5/24/20193942Math: 50. C# - MathNet.Numerics의 Matrix(행렬) 연산파일 다운로드1
11909정성태5/25/20192602.NET Framework: 837. C# - PLplot 사용 예제 [1]파일 다운로드1
11908정성태5/22/20191841.NET Framework: 836. C# - Python range 함수 구현파일 다운로드1
11907정성태6/4/20191407오류 유형: 541. msbuild - MSB4024 The imported project file "...targets" could not be loaded
11906정성태5/21/20191179.NET Framework: 835. .NET Core/C# - 리눅스 syslog에 로그 남기는 방법
11905정성태5/21/20191732.NET Framework: 834. C# - 폴더 경로 문자열에서 "..", "." 표기를 고려한 최종 문자열을 얻는 방법 - 두 번째 이야기
11904정성태5/21/20193726.NET Framework: 833. C# - Open Hardware Monitor를 이용한 CPU 온도 정보파일 다운로드1
11903정성태5/21/20192008오류 유형: 540. .NET Core - System.PlatformNotSupportedException: The named version of this synchronization primitive is not supported on this platform.
11902정성태5/21/20191314오류 유형: 539. mstest 실행 시 "The directory name is invalid." 오류 발생
11901정성태5/21/20192346오류 유형: 538. msbuild 오류 - Could not find a part of the path '%LOCALAPPDATA%\Temp\2\.NETFramework,Version=v4.0.AssemblyAttributes.cs'
11900정성태3/12/20202138오류 유형: 537. "sfc /scannow" 실행 중 시스템이 부팅되는 현상
11899정성태5/17/20192177Linux: 9. Linux에서 윈도우의 OutputDebugString 대신 사용할 수 있는 syslog [1]
11898정성태5/20/20192384VC++: 130. C++ string의 c_str과 data 함수의 차이점 [3]
11897정성태5/16/20194528오류 유형: 536. Visual Studio - "Developer Pack"을 설치했는데도 "대상 프레임워크" 목록에 나오지 않는 경우 [1]
11896정성태5/15/20193343개발 환경 구성: 440. C#, C++ - double의 Infinity, NaN 표현 방식파일 다운로드1
11895정성태5/12/20192211.NET Framework: 832. ML.NET Model Builder - 회귀(Regression), 다중 분류(Multi-class classification) 예제파일 다운로드1
11894정성태5/12/20193041VS.NET IDE: 135. Visual Studio - ML.NET Model Builder 소개 [1]
11893정성태5/10/20192247오류 유형: 535. C# 6.0 이상의 문법을 컴파일 시 오류가 발생한다면?
11892정성태5/10/20191642웹: 38. HTTP Cookie의 expires 시간 형식(RFC7231)
11891정성태8/12/20201990.NET Framework: 831. (번역글) .NET Internals Cookbook Part 12 - Memory structure, attributes, handles
11890정성태5/8/20191532개발 환경 구성: 439. "Visual Studio Enterprise is required to execute the test." 메시지와 관련된 코드 기록
11889정성태5/8/20191687개발 환경 구성: 438. mstest, QTAgent의 로그 파일 설정 방법
... 16  17  18  19  20  21  22  23  [24]  25  26  27  28  29  30  ...