Microsoft MVP성태의 닷넷 이야기
Graphics: 12. Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader) [링크 복사], [링크+제목 복사]
조회: 5391
글쓴 사람
정성태 (techsharer at outlook.com)
홈페이지
첨부 파일
 

Unity로 실습하는 Shader (8) - 다중 패스(Multi-Pass Shader)

Unity shader에서 다중 패스를 이용한 방법이 은근히 까다롭군요. 아래의 글을 읽고,

유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass
; http://rapapa.net/?p=2723
; https://github.com/inbgche/ShaderMixingSample/blob/master/Assets/Shader/FV_FV.shader

다음과 같이 그대로 베껴서 구현해 봤는데,

//Multi-Pass Shader Test. Rapapa.net
 
Shader "Test/Multi-Pass" {
    Properties {
    } 
 
    SubShader {
 
      Tags {"Queue" = "Geometry" "RenderType" = "Opaque" }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - RED          //
      ////////////////////////////////////////////////////////
 
      Pass {
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
        float4 vertex : POSITION;
        float4 color : COLOR;
        };
 
        struct vertexOutput
        {
        float4 pos : POSITION;
        float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
           return fixed4(1, 0, 0, 1);
        }
 
        ENDCG
      }
 
      ////////////////////////////////////////////////////////
      //Vertex-Fragment Functionality shader - GREEN          //
      ////////////////////////////////////////////////////////
 
      Pass {
 
        CGPROGRAM
 
        #pragma vertex vert
        #pragma fragment frag
 
        struct vertexInput
        {
          float4 vertex : POSITION;
          float4 color : COLOR;
        };
 
        struct vertexOutput
        {
          float4 pos : POSITION;
          float4 color : COLOR;
        };
 
        vertexOutput vert(vertexInput v) {
          vertexOutput o;
          o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
          o.color = v.color;
          return o;
        }
 
        fixed4 frag( vertexOutput i) : COLOR {
          return fixed4(i.color.r, 1, 0, 1);
        }
 
        ENDCG
 
      }
  }
 
  Fallback "Diffuse"
}

첫 번째 pass에서 붉은색을 반환하고,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(1, 0, 0, 1);
}

두 번째 pass에서 이전 값의 Red 값과 새롭게 Green 값을 합성한다고 하는데,

fixed4 frag( vertexOutput i) : COLOR {
    return fixed4(i.color.r, 1, 0, 1);
}

실제로 해보면 진짜 노란색이 나옵니다. 문제는, i.color의 rgb 값이 전부 1이기 때문에 그런 식으로 잘 동작하는 것처럼 보인 것입니다. 일례로 다음과 같이 해도 실행해 보면 노란색이 나옵니다.

fixed4 frag( vertexOutput i) : COLOR {
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.g, 1, 0, 1);
    // 이렇게 반환해도 노란색,
    return fixed4(i.color.b, 1, 0, 1);

    // 이렇게 반환하면 하얀색으로 출력
    return i.color;
}

"유니티에서 다른 타입의 쉐이더를 멀티 패스로 통합하기 / Unity merging different type shaders using multi pass" 원 글에서 참조 링크로 걸은 글에 보면,

Rules for Multi-pass Shaders in Unity 
; http://albertshih.blogspot.com/2014/11/rules-for-multi-pass-shaders-in-unity.html

다음과 같이 지적하고 있습니다.

(Each pass has its own properties that will not be "passed" on to other passes. For a list of those properties, check here)


QA에 답변과 종합해 보면,

Q: Can you put two vertex/fragment shaders together?
A: Yes, just put two passes with vertex/fragment shaders right next to each other. The second one will be drawn over the first one. (Note that some properties will be passed on from one pass to the other. For example, if you use a vertex shader to change the mesh geometry, the changes will still be there in the next pass.)


그러니까, 각각의 vertex shader에 들어온 vertexInput.color는 이전 패스에서 넘어온 값이 아닙니다. 이것은 초기화 값으로 Unity의 render target은 기본적으로 "white"로 칠해져 있으므로 다중 패스의 모든 vertex shader는 색상 값이 float4(1, 1, 1, 1)로 넘어오는 것입니다.

그리고, 나중에 실행되는 패스가 이전 패스에서 칠한 값에 상관없이 자신의 값으로 덮어쓰는 결과가 됩니다. 그러니까, 위의 멀티 패스는 전혀 사용할 수 없는 예제인 것입니다.




실제로 멀티 패스가 덧씌우는 동작을 하고 있는지 확인을 해볼까요?

이를 위해서는 투명 렌더링을 해보면 됩니다. 따라서 Blend 및 RednerType 옵션을 설정하고,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        // ...[생략]...
    }
}

첫 번째 패스에서 다음과 같이 Red만 설정하고 렌더링하면,

Pass 
{
    CGPROGRAM

    // ...[생략]...

    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;
        o.pos = UnityObjectToClipPos(v.vertex);
        o.color = v.color;
        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR
    {
        return fixed4(1, 0, 0, 1);
    }
    ENDCG
}

(모델을 Sphere로 했다고 가정했을 때) 화면에는 빨간색 구체가 그려집니다. 반면 fixed4(1,0,0,0)으로 alpha 값을 0으로 반환하면 Blend 옵션으로 인해 아무것도 안 그려지게 됩니다.

이렇게 빨간색 구체가 그려진 상태에서,

multi_pass_1.png

이제 두 번째 패스를 추가하겠습니다.

Pass 
{
    CGPROGRAM

    // ...[생략]...
    vertexOutput vert(vertexInput v)
    {
        vertexOutput o;

        if (v.vertex.x > 0.1) // 로컬 좌표계로 x가 0.1보다 큰 경우에는 Green 색상을 그리고,
        {
            o.color = float4(0, 1, 0, 1);
        }
        else
        {                     // 그렇지 않은 경우 alpha == 0을 주어 그리지 않게 만듦.
            o.color = float4(0, 0, 0, 0);
        }

        o.pos = UnityObjectToClipPos(v.vertex);

        return o;
    }

    fixed4 frag(vertexOutput i) : COLOR 
    {
        return i.color;
    }

    ENDCG
}

중간의 if 문의 역할은 의미를 두고 해석하지 말고, 단순히 덮어쓸 여부를 확인하기 위한 정도로만 보시면 됩니다. 즉, 일부는 Green 색상이 alpha == 1이므로 덮어 그릴 것이고, 일부는 alpha == 0이므로 덮어 그리지 않을 것입니다. 실제로 이것을 실행해 보면 다음과 같이 나옵니다.

multi_pass_2.png

이 정도면 어떤 것인지 확인이 되었겠죠? ^^




참고로, shader 코드는 Pass 외부로 빼서 공통 코드를 공유하는 것이 가능합니다. 즉, 아래와 같이 각각의 pass에서 구현하는 것도 가능하지만,

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.color = v.color;
                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return fixed4(1, 0, 0, 1);
            }
            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            struct vertexInput
            {
                float4 vertex : POSITION;
                float4 color : COLOR;
            };

            struct vertexOutput
            {
                float4 pos : POSITION;
                float4 color : COLOR;
            };

            vertexOutput vert(vertexInput v)
            {
                vertexOutput o;

                if (v.vertex.x > 0.1)
                {
                    o.color = float4(0, 1, 0, 1);
                }
                else
                {
                    o.color = float4(0, 0, 0, 0);
                }

                o.pos = UnityObjectToClipPos(v.vertex);

                return o;
            }

            fixed4 frag(vertexOutput i) : COLOR
            {
                return i.color;
            }

            ENDCG
        }
    }
}

다음과 같이 CGINCLUDE/ENDCG 쌍을 이용해 외부로 빼서 공통 코드는 재활용하는 것도 가능합니다.

Shader "My/multipassTestShader"
{
    Properties
    {
    }

    CGINCLUDE

        struct vertexInput
        {
            float4 vertex : POSITION;
            float4 color : COLOR;
        };

        struct vertexOutput
        {
            float4 pos : POSITION;
            float4 color : COLOR;
        };

        vertexOutput vert(vertexInput v)
        {
            vertexOutput o;
            o.pos = UnityObjectToClipPos(v.vertex);
            o.color = v.color;
            return o;
        }

        fixed4 frag(vertexOutput i) : COLOR
        {
            return fixed4(1, 0, 0, 1);
        }

        vertexOutput vert2(vertexInput v)
        {
            vertexOutput o;

            if (v.vertex.x > 0.1)
            {
                o.color = float4(0, 1, 0, 1);
            }
            else
            {
                o.color = float4(0, 0, 0, 0);
            }

            o.pos = UnityObjectToClipPos(v.vertex);

            return o;
        }

        fixed4 frag2(vertexOutput i) : COLOR
        {
            return i.color;
        }

    ENDCG

    SubShader
    {
        Tags{ "RenderType" = "Transparent" "Queue" = "Transparent" }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag

            ENDCG
        }

        Pass 
        {
            CGPROGRAM

            #pragma vertex vert2
            #pragma fragment frag2

            ENDCG
        }
    }
}




자, 그럼 우리가 원하는 멀티 패스를 어떻게 구현해야 하는 걸까요? 검색해 보면 다음의 결과가 있군요. ^^

CommandBuffer 를 이용한 Multipass Shader 기법 
; http://scripter.co.kr/298

근데, 좀 복잡합니다. ^^; 예전 글에서 구현한 Gaussian Blur가,

Unity로 실습하는 Shader (7) - Blur (평균값, 가우스, 중간값) 필터
; https://www.sysnet.pe.kr/2/0/11620

사용한 2차원 커널을 1차원 커널로 x와 y에 대해 멀티 패스로 구현하면 된다고 했는데요. "CommandBuffer 를 이용한 Multipass Shader 기법" 글에서 설명한 것처럼 복잡하다면 차라리 2차원 커널을 사용해 단일 shader로 그리는 것이 더 효율적인 것 같습니다.




[이 글에 대해서 여러분들과 의견을 공유하고 싶습니다. 틀리거나 미흡한 부분 또는 의문 사항이 있으시면 언제든 댓글 남겨주십시오.]

[연관 글]


donaricano-btn



[최초 등록일: ]
[최종 수정일: 7/27/2018 ]

Creative Commons License
이 저작물은 크리에이티브 커먼즈 코리아 저작자표시-비영리-변경금지 2.0 대한민국 라이센스에 따라 이용하실 수 있습니다.
by SeongTae Jeong, mailto:techsharer@outlook.com

비밀번호

댓글 쓴 사람
 




... 16  17  18  19  20  21  22  23  24  25  26  27  [28]  29  30  ...
NoWriterDateCnt.TitleFile(s)
11814정성태2/12/20191789오류 유형: 512. VM(가상 머신)의 NT 서비스들이 자동 시작되지 않는 문제
11813정성태2/12/20192251.NET Framework: 809. C# - ("Save File Dialog" 등의) 대화 창에 확장 속성을 보이는 방법
11812정성태1/2/20201608오류 유형: 511. Windows Server 2003 VM 부팅 후 로그인 시점에 0xC0000005 BSOD 발생
11811정성태2/11/20192487오류 유형: 510. 서버 운영체제에 NVIDIA GeForce Experience 실행 시 wlanapi.dll 누락 문제
11810정성태2/11/20191723.NET Framework: 808. .NET Profiler - GAC 모듈에서 GAC 비-등록 모듈을 참조하는 경우의 문제
11809정성태2/11/20192060.NET Framework: 807. ClrMD를 이용해 메모리 덤프 파일로부터 특정 인스턴스를 참조하고 있는 소유자 확인
11808정성태2/8/20192851디버깅 기술: 123. windbg - 닷넷 응용 프로그램의 메모리 누수 분석
11807정성태1/29/20192339Windows: 156. 가상 디스크의 용량을 복구 파티션으로 인해 늘리지 못하는 경우 [3]
11806정성태1/29/20191877디버깅 기술: 122. windbg - 덤프 파일로부터 PID와 환경 변수 등의 정보를 구하는 방법
11805정성태1/28/20192959.NET Framework: 806. C# - int []와 object []의 차이로 이해하는 제네릭의 필요성 [4]파일 다운로드1
11804정성태1/24/20192449Windows: 155. diskpart - remove letter 이후 재부팅 시 다시 드라이브 문자가 할당되는 경우
11803정성태1/10/20192346디버깅 기술: 121. windbg - 닷넷 Finalizer 스레드가 멈춰있는 현상
11802정성태1/7/20192527.NET Framework: 805. 두 개의 윈도우를 각각 실행하는 방법(Windows Forms, WPF)파일 다운로드1
11801정성태1/1/20192759개발 환경 구성: 427. Netsh의 네트워크 모니터링 기능 [3]
11800정성태12/28/20183488오류 유형: 509. WCF 호출 오류 메시지 - System.ServiceModel.CommunicationException: Internal Server Error
11799정성태12/19/20183517.NET Framework: 804. WPF(또는 WinForm)에서 UWP UI 구성 요소 사용하는 방법 [3]파일 다운로드1
11798정성태12/19/20183263개발 환경 구성: 426. vcpkg - "Building vcpkg.exe failed. Please ensure you have installed Visual Studio with the Desktop C++ workload and the Windows SDK for Desktop C++"
11797정성태3/7/20202238개발 환경 구성: 425. vcpkg - CMake Error: Problem with archive_write_header(): Can't create '' 빌드 오류
11796정성태12/19/20182011개발 환경 구성: 424. vcpkg - "File does not have expected hash" 오류를 무시하는 방법
11795정성태12/19/20183478Windows: 154. PowerShell - Zone 별로 DNS 레코드 유형 정보 조회 [1]
11794정성태12/17/20181916오류 유형: 508. Get-AzureWebsite : Request to a downlevel service failed.
11793정성태12/16/20182239개발 환경 구성: 423. NuGet 패키지 제작 - Native와 Managed DLL을 분리하는 방법
11792정성태12/11/20182611Graphics: 34. .NET으로 구현하는 OpenGL (11) - Per-Pixel Lighting파일 다운로드1
11791정성태6/23/20202707VS.NET IDE: 130. C/C++ 프로젝트의 시작 프로그램으로 .NET Core EXE를 지정하는 경우 닷넷 디버깅이 안 되는 문제 [1]
11790정성태12/11/20182393오류 유형: 507. Could not save daemon configuration to C:\ProgramData\Docker\config\daemon.json: Access to the path 'C:\ProgramData\Docker\config' is denied.
11789정성태12/10/20185310Windows: 153. C# - USB 장치의 연결 및 해제 알림을 위한 WM_DEVICECHANGE 메시지 처리파일 다운로드1
... 16  17  18  19  20  21  22  23  24  25  26  27  [28]  29  30  ...